SET NODOECHO
SET NOCOLOR
SET NOWARN
************************************************************************** 
** THIS FILE CALCULATES ELECTRICITY TNSP MULTILATERAL TFP FOR 2006-2024 **
** FOR TRG ONLY **********************************************************
**************************************************************************
** VARIABLES ARE IN ORDER: YEAR, TOTAL REVENUE, GWH, RATCHETED MAX DEMAND,
** END-USER NOS, CIRCUIT KMS, ENERGY NOT SUPPLIED, PRICE EN NOT SUPPLIED,
** OPEX, PRICE OF OPEX, OVERHEAD MVAKMS, UNDERGROUND MVAKMS, *************
** MVA TRANSFORMER CAPACITY, USER COST OF OVERHEAD LINES, ****************
** USER COST OF UNDERGROUND CABLES, USER COST OF TRANSFORMERS & OTHER, ***
** MAX DEMAND, MAX DEMADN INDEX, ADJ VENS ********************************
**************************************************************************
** OUTPUTS ARE GWH, RATCHETED MAX DEMAND, END-USER NOs, CIRCUIT LENGTH, **
** ADJUSTED ENERGY NOT SERVED ********************************************
** USING LEONTIEF COST FN SHARES OF 0.09, 0.29, 0.09, 0.53, RESP'LY ******
** INPUTS ARE OPEX, OH MVAKMS, UG MVAKMS, MVA TRF CAP & OTHER ASSETS *****
**************************************************************************
** THIS VERSION USES AER VCRs WITH 2.5% STPIS-BASED CAP ******************
**************************************************************************
SMPL 1 19
read(TRGdata.csv) TNSPYear Revenue Energy RMDemand EndUser CircLen EnNotSer PrEnNotS &	
  Opex PrOpex OHLines UGCables Transf AUCOH	AUCUG AUCTrans MD MDIndex AdjVENS / skiplines=1
GENR X2=OHLines
GENR X3=UGCables
GENR X4=Transf
GENR R1=PrOpex
GENR VI1=Opex
GENR VI2=AUCOH
GENR VI3=AUCUG
GENR VI4=AUCTrans
GENR Q1=Energy
GENR Q2=RMDemand
GENR Q3=EndUser
GENR Q4=CircLen
genr Q5=EnNotSer
GENR GR=Revenue+AdjVENS
GENR V1=GR*0.09445
GENR V2=GR*0.28685
GENR V3=GR*0.0933
GENR V4=GR*0.5254
GENR V5=-1*AdjVENS
GENR X1=VI1/R1
DO #=1,5
GENR P#=V#/Q#
GENR SO#=V#/Revenue
STAT SO# / MEAN=SO#M
GENR LQ#=LOG(Q#)
STAT LQ# / MEAN=LQ#M
GENR LQ#L=LAG(LQ#)
GENR SO#L=LAG(SO#)
ENDO
GENR TC=VI1+VI2+VI3+VI4
GENR VK=VI2+VI3+VI4
DO #=1,4
GENR R#=VI#/X#
GENR SI#=VI#/TC
STAT SI# / MEAN=SI#M
GENR LX#=LOG(X#)
STAT LX# / MEAN=LX#M
GENR LX#L=LAG(LX#)
GENR SI#L=LAG(SI#)
ENDO
DO #=2,4
GENR SK#=VI#/VK
STAT SK# / MEAN=SK#M
GENR SK#L=LAG(SK#)
ENDO
SMPL 2 19
**********************************************************************
** MULTILATERAL CCD OUTPUT INDEX *************************************
**********************************************************************
GENR LNOI=0.5*((SO1+SO1M)*(LQ1-LQ1M)+(SO2+SO2M)*(LQ2-LQ2M)+(SO3+SO3M)*(LQ3-LQ3M)+ &
(SO4+SO4M)*(LQ4-LQ4M)+(SO5+SO5M)*(LQ5-LQ5M))-0.5*((SO1L+SO1M)*(LQ1L-LQ1M)+(SO2L+SO2M)*(LQ2L-LQ2M)+ &
(SO3L+SO3M)*(LQ3L-LQ3M)+(SO4L+SO4M)*(LQ4L-LQ4M)+(SO5L+SO5M)*(LQ5L-LQ5M))
GENR OI=EXP(LNOI)
**********************************************************************
** MULTILATERAL CCD INPUT INDEX **************************************
**********************************************************************
GENR LNII=0.5*((SI1+SI1M)*(LX1-LX1M)+(SI2+SI2M)*(LX2-LX2M)+(SI3+SI3M)*(LX3-LX3M)+ &
(SI4+SI4M)*(LX4-LX4M))-0.5*((SI1L+SI1M)*(LX1L-LX1M)+(SI2L+SI2M)*(LX2L-LX2M)+ &
(SI3L+SI3M)*(LX3L-LX3M)+(SI4L+SI4M)*(LX4L-LX4M))
GENR II=EXP(LNII)
**********************************************************************
** MULTILATERAL CCD CAPITAL INPUT INDEX ******************************
**********************************************************************
GENR LNKI=0.5*((SK2+SK2M)*(LX2-LX2M)+(SK3+SK3M)*(LX3-LX3M)+ &
(SK4+SK4M)*(LX4-LX4M))-0.5*((SK2L+SK2M)*(LX2L-LX2M)+ &
(SK3L+SK3M)*(LX3L-LX3M)+(SK4L+SK4M)*(LX4L-LX4M))
GENR KI=EXP(LNKI)
**********************************************************************
** MULTILATERAL OUTPUT CONTRIBUTIONS TO MTFP *************************
**********************************************************************
DO #=1,5
GENR OC#=0.5*(SO#+SO#M)*(LQ#-LQ#M)-0.5*(SO#L+SO#M)*(LQ#L-LQ#M)
ENDO
**********************************************************************
** MULTILATERAL INPUT CONTRIBUTIONS TO MTFP **************************
**********************************************************************
DO #=1,4
GENR IC#=-1*(0.5*(SI#+SI#M)*(LX#-LX#M)-0.5*(SI#L+SI#M)*(LX#L-LX#M))
ENDO
**********************************************************************
** MULTILATERAL CUMULATIVE INDEXES ***********************************
**********************************************************************
SMPL 1 19
GENR OUTIND=0.0
GENR INPIND=0.0
GENR KIND=0.0
GENR OUTIND(1)=1.0
GENR INPIND(1)=1.0
GENR KIND(1)=1.0
DO #=2,19
GENR OUTIND(#)=OUTIND(#-1)*OI(#)
GENR INPIND(#)=INPIND(#-1)*II(#)
GENR KIND(#)=KIND(#-1)*KI(#)
ENDO
GENR PRODIND=OUTIND/INPIND
DO #=1,5
GEN1 BASEO#=Q#(1)
GENR QB#=Q#/BASEO#
ENDO
DO #=1,4
GEN1 BASE#=X#(1)
GENR XB#=X#/BASE#
GENR PP#=OUTIND/XB#
ENDO
GENR PPK=OUTIND/KIND
PRINT TNSPYear OUTIND INPIND PRODIND PP1 PPK / WIDE
PRINT TNSPYEAR PP1 PPK PP2-PP4 / WIDE
PRINT TNSPYEAR QB1-QB5 MDIndex OUTIND / WIDE
PRINT TNSPYEAR XB1-XB4 KIND INPIND / WIDE
PRINT TNSPYEAR SO1-SO5 / WIDE
PRINT TNSPYEAR SI1-SI4
SMPL 2 19
PRINT TNSPYEAR OC1-OC5 / WIDE
PRINT TNSPYEAR IC1-IC4
SMPL 1 19
GENR T=TIME(0)
GENR LTFP=LOG(PRODIND)
GENR LQO=LOG(OUTIND)
GENR LQI=LOG(INPIND)
GENR LPP1=LOG(PP1)
GENR LPPK=LOG(PPK)
**************************************************************************
** ESTIMATE TREND GROWTH RATES OVER PERIOD 2006-2024 *********************
**************************************************************************
OLS LQO T
OLS LQI T
OLS LTFP T
OLS LPP1 T
OLS LPPK T
SMPL 1 7
**************************************************************************
** ESTIMATE TREND GROWTH RATES OVER PERIOD 2006-2012 *********************
**************************************************************************
OLS LQO T
OLS LQI T
OLS LTFP T
OLS LPP1 T
OLS LPPK T
SMPL 7 19
**************************************************************************
** ESTIMATE TREND GROWTH RATES OVER PERIOD 2012-2024 *********************
**************************************************************************
GENR T=TIME(0)
OLS LQO T
OLS LQI T
OLS LTFP T
OLS LPP1 T
OLS LPPK T
STOP
