FI 11 AER\DINDDATA.TXT
SET NODOECHO
SET NOCOLOR
**************************************************************************
** THIS FILE CALCULATES ELECTRICITY DISTRIBUTION INDUSTRY TFP ************
** FOR 2006-2015 *********************************************************
**************************************************************************
** VARIABLES ARE IN ORDER: YEAR, TOTAL REVENUE, GWH, RATCHETED MAX DEMAND,
** CONNECTION NO, CIRCUIT KMS, MINS OFF SUPPLY, PRICE MIN OFF-SUPPLY, ****
** OPEX, PRICE OF OPEX, OVERHEAD ST MVAKMS, OVERHEAD DN MVAKMS, **********
** UNDERGROUND ST MVAKMS, UNDERGROUND DN MVAKMS, *************************
** MVA TRANSFORMER CAPACITY, USER COST OF OVERHEAD ST LINES, *************
** USER COST OF OVERHEAD DN LINES, USER COST OF UNDERGROUND ST CABLES, ***
** USER COST OF UNDERGROUND DN CABLES, USER COST OF TRANSFORMERS & OTHER *
**************************************************************************
** WE USE LEONTIEF COST FUNCTION SHARES OF 0.128, 0.176, 0.458 AND 0.238 ON
** OUTPUTS OF GWH, RATCHETED MAX DEMAND, CONNECTION NO, CIRCUIT LENGTH ***
** RELIABILITY IS INCLUDED AS 5th OUTPUT USING DNSP VCRs/2 ***************
** INPUTS ARE OPEX, OH ST MVAKMS, OH DN MVAKMS, UG ST MVAKMS, ************
** UG DN MVAKMS, MVA TRF CAP EXCL FIRST STAGE & OTHER ASSETS *************
** WITH EXOGENOUS CAPITAL AUCs *******************************************
**************************************************************************
** THIS FILE REPORTS OUTPUT SPECIFICATION #4A & INPUT SPECIFICATION #2A **
**************************************************************************
** THIS VERSION USES CURRENT AEMO VCRs ***********************************
**************************************************************************
SMPL 1 10
READ (11) YEAR TR Q1 Q2 Q3 Q4 Q5 P5 VI1 R1 X2 X3 X4 X5 X6 VI2 VI3 VI4 VI5 VI6 / SKIPLINES=2
GENR GR=TR+P5*Q5/1000
GENR V1=GR*0.128
GENR V2=GR*0.176
GENR V3=GR*0.458
GENR V4=GR*0.238
GENR V5=-1*P5*Q5/1000
GENR X1=VI1/R1
DO #=1,5
GENR P#=V#/Q#
GENR SO#=V#/TR
ENDO
DO #=2,6
GENR R#=VI#/X#
ENDO
**********************************************************************
** OUTPUT INDEX - SPECIFICATION #4a **********************************
**********************************************************************
INDEX Q1-Q5 P1-P5 / NOLIST NOALTERN CHAIN FISHER=QO QFISHER=PO
**********************************************************************
** INPUT INDEX - SPECIFICATION #2a ***********************************
**********************************************************************
INDEX X1-X6 R1-R6 / NOLIST NOALTERN CHAIN FISHER=QI QFISHER=PI
INDEX X2-X6 R2-R6 / NOLIST NOALTERN CHAIN FISHER=Qk QFISHER=Pk
**********************************************************************
** TFP INDEX - OUTPUT SPEC #4a, INPUT SPEC #2a ***********************
**********************************************************************
GENR TFP=QO/QI
DO #=1,5
GEN1 BASEO#=Q#(1)
GENR QB#=Q#/BASEO#
ENDO
DO #=1,6
GEN1 BASE#=X#(1)
GENR XB#=X#/BASE#
GENR PP#=QO/XB#
ENDO
GENR PPK=QO/QK
PRINT YEAR QB1-QB5 QO / WIDE
PRINT YEAR SO1-SO5 / WIDE
PRINT YEAR XB1-XB6 / WIDE
PRINT YEAR QK QI / WIDE
PRINT YEAR QO QI TFP
PRINT YEAR PP1 PPK PP2-PP6 / WIDE
STOP